Indirekter Bezug auf ein anderes Tabellenblatt  
Versionen: Excel 2013/2010 (32- und 64-Bit), 2007, 2003 und Office 365 (Excel)  
  
**FRAGE:** Ich habe eine Arbeitsmappe mit mehreren Tabellenblättern angelegt. Die Blätter heißen "Januar", "Februar" usw. In einer weiteren Tabelle summiere ich Werte aus den Monatsblättern, zum Beispiel  
  
=Januar!B4+Februar!B4  
  
Nun möchte ich möglichst schnell bestimmen, welche Monatswerte addiert werden. Es wäre praktisch, wenn ich dann einfach "Januar" und "Februar" in zwei Zellen eingeben könnte und die oben genannte Formel automatisch die Werte aus B4 der Januar- und der Februar-Tabelle addieren würde. Leider funktioniert es aber nicht, die Formel in so etwas wie "=A1!B4+A2!B4" zu ändern (Excel scheint dann eine Dateien mit den Namen "A1" und "A2" zu suchen). Wissen Sie Rat?  
*Diverse Anfragen*  
  
**ANTWORT:** Excel wertet eine Bezeichnung mit nachgestelltem "!" immer als Blatt- oder Dateinamen. Das macht Excel ja auch in Ihrer Formel "=Januar!B4+Februar!B4". Wenn Sie möchten, dass Excel den Inhalt einer Zelle - und nicht die Zelladresse selbst - als Bezug interpretiert, müssen Sie mit einer INDIREKT-Funktion arbeiten. Damit erreichen Sie genau das von Ihnen gewünschte Resultat.  
  
Wenn Sie die Namen der Tabellenblätter, aus denen Sie Werte summieren wollen, beispielsweise in die Zellen A1 und A2 eingegeben haben, können Sie mit folgender Formel jeweils die Zahlen aus B4 dieser Tabellenblätter addieren:  
  
=INDIREKT("'"&A1&"'!B4")+  
INDIREKT("'"&A2&"'!B4")  
  
Die INDIREKT-Funktion wandelt einen Textwert in einen Bezug um, weshalb Sie auch die Adressen der Zellen, aus denen Sie Werte addieren wollen, in die Zeichenfolge der INDIREKT-Funktion einschließen müssen. Die Verweise auf die Inhalte von A1 und A2 verknüpfen Sie mit dem Verkettungsoperator "&".  
  
Eine zusätzliche Besonderheit sind die einfachen Hochkommata, die den Blattbezug umgeben. Sie sind erforderlich, um auch mit Blattnamen, die Leerzeichen enthalten, arbeiten zu können.  
  
Als Erweiterung des Formelbeispiels können Sie natürlich auch auf die Zellen in den Tabellenblättern indirekt verweisen, beispielsweise indem Sie die Adresse "B4" als Text in Zelle A3 eingeben. Die Formel müssten Sie dann wie folgt anpassen:  
  
=INDIREKT("'"&A1&"'!"&A3)+  
INDIREKT("'"&A2&"'!"&A3)