IBAN-Zahlen richtig verarbeiten

Teil 1  
Versionen: Excel 2013, 2010, 2007, 2003 und 2002/XP  
  
Allmählich wird es Zeit, Bankverbindungsdaten auf IBAN (International Bank Account Number) umzustellen, denn ab 2014 soll die neue Kontonummer auch für den Zahlungsverkehr im Inland Pflicht werden. Da stellt sich die Frage, wie Sie IBAN-Daten am besten in Excel erfassen. Mit den Hinweisen aus diesem Beitrag gehen Sie allen möglicherweise auftretenden Problemen aus dem Weg.  
  
Die IBAN eines deutschen Kontos setzt sich aus dem Länderkürzel "DE", einer zweistelligen Prüfsumme, der alten Bankleitzahl sowie der alten Kontonummer zusammen. Die Länge beträgt genau 22 Zeichen.  
  
Eine österreichische IBAN ist nur 20 Stellen lang und sie beginnt mit "AT", während eine schweizerische IBAN 21 Stellen umfasst und mit "CH" beginnt. Ansonsten ähnelt der Aufbau einer deutschen IBAN.  
  
Notiert werden IBAN üblicherweise in einem Format, das die Kontonummer jeweils in Viererblöcke aufteilt. Eine deutsche IBAN würde beispielsweise wie folgt aussehen:  
  
DE39 7204 0046 0110 6608 01  
  
Das wirft die Frage auf, ob sich eine solche Formatierung nicht automatisch erreichen lässt, nachdem Sie die IBAN zunächst ohne Leerzeichen eingegeben haben. Vielleicht denken Sie da als erstes an ein benutzerdefiniertes Zahlenformat. Da stört natürlich das Länderkürzel, denn damit kann Excel die IBAN nicht als Zahl erkennen.  
  
So könnten Sie auf die Idee kommen, nur den Zahlenanteil der IBAN in die Excel-Tabelle einzutragen und das Länderkürzel womöglich mit Hilfe des benutzerdefinierten Zahlenformats hinzuzufügen. So wird es beim Währungsformat ja auch gemacht, nur dass dort das Währungssymbol am Ende steht.  
  
Versuchen Sie ruhig einmal, den 20-stelligen Zahlenanteil einer IBAN in eine Tabellenzelle einzugeben. Sie werden feststellen, dass Excel die Zahl zunächst in Exponentialschreibweise darstellt. Aus "39720400460110660801" wird dann zum Beispiel "3,97204E+19" - nicht gerade das, was Sie sich vorgestellt hatten.  
  
Aber Sie wollten ja ohnehin ein benutzerdefiniertes Zahlenformat zuweisen. Für eine deutsche IBAN müsste das Format so aussehen:  
  
"DE"00 0000 0000 0000 0000 00  
  
Wenn Sie die Zelle mit der IBAN entsprechend formatieren, erhalten Sie tatsächlich die gewünschte Einteilung in Viererblöcke und auch das Länderkürzel wird ordnungsgemäß an den Anfang gestellt.  
  
Aber haben Sie die Kontonummer schon ganz genau betrachtet? Ihnen wird auffallen, dass Excel die letzten Stellen eigenmächtig auf den Wert "0" setzt. Das liegt keineswegs daran, dass die Zahl vorher in Exponentialschreibweise angezeigt wurde. Es ist vielmehr ein "ganz natürliches Verhalten" von Excel.  
  
Excel kann Zahlen nämlich nur bis zu einer Genauigkeit von 15 signifikanten Stellen abbilden. Grund dafür ist die IEEE-Spezifikation 754, auf der Excel basiert und mit der die Speicherung von Gleitkommazahlen in binären Computersystemen definiert wird. Das führt dazu, dass alle Stellen nach der 15. signifikanten Stelle auf null gesetzt werden. Somit ist auch klar, dass Sie eine 20-stellige IBAN niemals vollständig in Excel erfassen können - zumindest nicht als Zahl.  
  
Wenn Sie nicht unbeabsichtigt die letzten Ziffern einer IBAN unterschlagen wollen, merken Sie sich also:  
  
Geben Sie eine IBAN immer als Text in eine Excel-Tabelle ein!  
  
Das erreichen Sie folgendermaßen:

* weisen Sie den Zellen vorab das Zahlenformat "Text" zu
* beginnen Sie die Eingabe der IBAN mit einem einfachen Hochkomma - etwa:

'39720400460110660801

* geben Sie gleich die vollständige IBAN mit dem einleitenden Länderkürzel ein

Bleibt noch das Problem mit der IBAN-Formatierung in Viererblöcken. Da Sie eine IBAN ohnehin als Text erfassen müssen, können Sie natürlich schon während der Eingabe für die passende Schreibweise sorgen. Diese Option haben Sie allerdings nicht, wenn Sie Kontodaten aus anderen Quellen in Ihre Excel-Tabelle importieren.  
  
Erfreulicherweise gibt es eine komfortable Lösung des Problems: eine selbst gemachte Tabellenfunktion, mit der Sie unformatierte IBAN automatisch in formatierte IBAN umwandeln. Wie das funktioniert, erfahren Sie im zweiten Teil dieses Tipps.

IBAN-Zahlen richtig verarbeiten, Teil 2  
Versionen: Excel 2013, 2010, 2007, 2003 und 2002/XP  
  
Die neuen Kontonummern in Form der international gültigen IBAN (International Bank Account Number) können in einer Excel-Tabelle durchaus Probleme bereiten, wie der erste Teil dieses Tipps gezeigt hat. Noch schwieriger wird es, IBAN in der allgemein gültigen Schreibweise zu erfassen. Die benutzerdefinierte Tabellenfunktion, die wir Ihnen in diesem Teil unseres Tipps vorstellen, nimmt Ihnen die Arbeit ab.  
  
Mit der von uns entwickelten Tabellenfunktion lassen sich nicht nur deutsche, sondern auch internationale IBAN formatiert ausgeben. Sie können sogar das Länderkürzel weglassen, woraufhin automatisch ein Standardkürzel eingefügt wird. Oder Sie erfassen Kontonummer und Länderkürzel in separaten Zellen: Dann setzt unsere Funktion automatisch Kürzel und Kontonummer zu einer formatierten IBAN zusammen.  
  
Um die Funktion in Ihrer Arbeitsmappe einzusetzen, gehen Sie wie folgt vor:

* Öffnen Sie die Arbeitsmappe, in der Sie formatierte IBAN ausgeben lassen wollen.
* Wechseln Sie mit **Alt+F11** in die Programmierumgebung von Excel.
* Wählen Sie das Menü *Einfügen-Modul* an.
* Geben Sie in das daraufhin geöffnete Codefenster den folgenden VBA-Code ein:

Function IBAN( \_  
    Kontonummer, \_  
    Optional Laenderkuerzel) \_  
  As String  
  
Dim lk As String  
Dim kn As String  
  
  If IsMissing(Laenderkuerzel) Then  
    lk = "DE"  
  Else  
    lk = Laenderkuerzel  
  End If  
  
  If IsNumeric(Left(Kontonummer, 2)) Then  
    kn = lk & Replace(CStr(Kontonummer), " ", "")  
  Else  
    kn = Replace(CStr(Kontonummer), " ", "")  
  End If  
  
  IBAN = UCase(Vierergruppen(kn))  
End Function  
  
Function Vierergruppen( \_  
    ByVal IBANpur As String) \_  
  As String  
Dim lngLen As Long  
Dim i As Long  
Dim strTemp As String  
  
  lngLen = Len(IBANpur)  
  For i = 1 To lngLen Step 4  
    strTemp = strTemp & Mid(IBANpur, i, 4) & " "  
  Next i  
  Vierergruppen = Trim(strTemp)  
End Function

* Verlassen Sie die Programmierumgebung per *Datei-Schließen und zurück zu Microsoft Excel*.
* Speichern Sie die Änderungen. Beachten Sie, dass Sie die Datei in Excel 2013, 2010 und 2007 jetzt als "Arbeitsmappe mit Makros" speichern müssen. Wählen Sie dazu *Datei-Speichern unter* oder in Excel 2007 *Office*-Schaltfläche-*Speichern unter* an und ändern Sie den *Dateityp*.

In Ihrer Arbeitsmappe steht Ihnen ab sofort eine neue Tabellenfunktion namens "IBAN" zur Verfügung - mit folgender Syntax:  
  
=IBAN(<Kontonummer>;[<Länderkürzel>])  
  
Wenn die unformatierte Kontonummer zum Beispiel in Zelle A4 steht, könnten Sie in Zelle B4 mit folgender Formel die formatierte IBAN berechnen:  
  
=IBAN(A4)  
  
Sollte die Kontonummer in A4 nicht mit einem Länderkürzel beginnen, stellt die Funktion automatisch "DE" voran. Das lässt sich im Programmcode auch auf andere Standardkürzel wie "AT" oder "CH" umstellen.  
  
Für den Fall, dass Sie Länderkürzel und Kontonummer in getrennten Zellen eingegeben haben, bietet die Funktion "IBAN" einen zweiten, optionalen Parameter. Wenn Sie etwa die Kontonummer in Zelle A4 und das Länderkürzel in Zelle B4 eingegeben haben, könnten Sie die formatierte IBAN mit folgender Formel aus den beiden Teilinformationen zusammensetzen:  
  
=IBAN(A4;B4)  
  
Wenn Sie das Standard-Länderkürzel ändern oder programmiertechnische Details der Funktion "IBAN" kennen lernen wollen, wechseln Sie mit Alt+F11 in die Programmierumgebung und werfen Sie einen Blick auf den Programmcode.  
  
Die Funktion besitzt zwei Parameter: erforderlich ist der Parameter "Kontonummer", optional der Parameter "Laenderkuerzel".  
  
Anfangs prüft die Funktion, ob der zweite Parameter fehlt:  
  
If IsMissing(Laenderkuerzel)  
  
In diesem Fall wird die Variable "lk" auf den Text "DE" gesetzt. Bei Bedarf können Sie hier einen anderen Standardwert einstellen. Wenn Kontonummern ohne Länderkürzel beispielsweise automatisch als österreichische IBAN interpretiert werden sollen, ändern Sie die Codezeile in  
  
lk = "AT"  
  
In der zweiten If-Abfrage wird geprüft, ob die ersten beiden Stellen der übergebenen Kontonummer numerisch sind. Dann fehlt das Länderkürzel und der Kontonummer wird automatisch das zuvor ermittelte Länderkürzel vorangestellt. Gleichzeitig werden mit einer Replace-Funktion alle Leerzeichen aus der Kontonummer entfernt, so dass Sie auf jeden Fall eine zusammenhängende Zeichenfolge erhalten.  
  
Sollte es sich bei den ersten beiden Stellen der Kontonummer nicht um Ziffern handeln, ist davon auszugehen, dass die Kontonummer bereits ein Länderkürzel enthält. Dann müssen nur noch eventuell vorhandene Leerzeichen beseitigt werden.  
  
Zum Formatieren der IBAN greift die Funktion auf eine Hilfsfunktion namens "Vierergruppen" zurück. Diese Funktion befindet sich weiter unten im aktuellen Codefenster.  
  
Ihre Aufgabe ist es, jeweils nach vier Zeichen der Kontonummer ein Leerzeichen einzufügen. Dazu ermittelt die Hilfsfunktion "Vierergruppen" als erstes die Länge der Kontonummer, um diesen Wert als Obergrenze für die nachfolgende For-Schleife einzusetzen.  
  
In der Schleife wird die formatierte IBAN dann Schritt für Schritt zusammengesetzt, wobei eine Mid-Funktion immer wieder die nächsten vier Zeichen aus der Original-Kontonummer herausgreift und ihnen ein Leerzeichen anhängt.  
  
Überflüssige Leerzeichen am Ende der formatierten IBAN beseitigt eine Trim-Funktion.  
  
So muss die Hauptfunktion "IBAN" das durch "Vierergruppen" ermittelte Ergebnis nur noch per "UCase" in Großbuchstaben umwandeln, um die korrekt formatierte IBAN als Endergebnis zurückzugeben.