Bcc Empfänger gesendeter Mails drucken  
Versionen: Outlook 2016/2013/2010 (32- und 64-Bit), 2007, 2003 und Office 365 (Outlook)  
  
**FRAGE:** Wenn ich eine gesendete E-Mail ausdrucke, gibt Outlook die von mir eingesetzten Bcc-Empfänger nicht aus. Gibt es irgendeine Druckoption, mit der ich das Bcc-Feld in den Druckvorgang einschließen kann? Oder haben Sie eine Makrolösung zum Drucken des Bcc-Feldes?  
*G. Igel*  
  
**ANTWORT:** Womöglich betrachtet Microsoft das Fehlen des Bcc-Feldes beim Drucken als Sicherheitsfeature. Schließlich sollen die Bcc-Empfänger einer E-Mail anderen verborgen bleiben. Dass sie aber auch Ihnen als Absender verborgen bleiben, wenn Sie die E-Mail drucken, ist nicht nachvollziehbar - zumal das Bcc-Feld im Nachrichtenfenster der gesendeten E-Mail durchaus zu sehen ist.  
  
Die unkomplizierteste Lösung des Problems ist ein Makro, das Sie alternativ zum üblichen Druckbefehl einsetzen können. Mit folgenden Schritten fügen Sie das Makro Ihrer Outlook-Umgebung hinzu:

* Drücken Sie **Alt+F8**, um das Dialogfenster *Makros* zu öffnen.
* Geben Sie im Feld *Makroname* folgende Bezeichnung ein:

DruckenMitBcc

* Klicken Sie auf die Schaltfläche *Erstellen*.
* Sie gelangen automatisch in die Entwicklungsumgebung von Outlook, wo bereits ein Prozedurgerüst für das Makro "DruckenMitBcc" eingefügt wurde. Ergänzen Sie dieses Gerüst wie folgt:

Sub DruckenMitBcc()  
Dim olMail As Object  
Dim olProp As Outlook.UserProperty  
  
  On Error Resume Next  
  
  Select Case TypeName(Application.ActiveWindow)  
    Case "Explorer" 'Ordnermarkierung  
      Set olMail = Application.ActiveExplorer \_  
          .Selection.Item(1)  
    Case "Inspector" 'geöffnetes Fenster  
      Set olMail = Application.ActiveInspector \_  
          .CurrentItem  
    Case Else  
      'andere Fälle ausschließen  
  End Select  
  
  If olMail.MessageClass = "IPM.Note" Then  
    Set olProp = olMail \_  
        .UserProperties("BCC-Empfänger")  
    If olProp Is Nothing Then  
      Set olProp = olMail.UserProperties \_  
          .Add("BCC-Empfänger", olText, False)  
    End If  
  
    olProp.Value = olMail.BCC  
    olMail.PrintOut  
  
    'UserProperty nach dem Drucken wieder löschen  
    olProp.Delete  
    olMail.Save  
  End If  
  
  Set olProp = Nothing  
  Set olMail = Nothing  
End Sub

* Wählen Sie *Datei-VbaProject.OTM speichern* an.
* Verlassen Sie die Entwicklungsumgebung per *Datei-Schließen und zurück zu Microsoft Outlook*.

Ab sofort können Sie gesendete E-Mails auch mit den Bcc-Empfängern drucken. Dazu gehen Sie folgendermaßen vor:

1. Markieren Sie die gewünschte E-Mail in Ihrem Ordner für gesendete Elemente oder öffnen Sie die E-Mail per Doppelklick in einem eigenen Fenster. - Das Makro berücksichtigt beide Varianten.
2. Öffnen Sie mit **Alt+F8** wieder das Dialogfenster *Makros*.
3. Markieren Sie den Makronamen "DruckenMitBcc" und klicken Sie auf *Ausführen*.
4. Outlook gibt die Nachricht umgehend auf dem Standarddrucker aus.

Das Makro wendet dabei einen Trick an, indem es nicht etwa im Hintergrund die Druckeinstellungen des Bcc-Feldes verändert. Vielmehr legt es ein neues, benutzerdefiniertes Feld namens "Bcc-Empfänger" an, welches es mit den Bcc-Empfängern füllt. Dieses Feld druckt Outlook automatisch unter dem Nachrichtenkopf aus. Am Ende wird das benutzerdefinierte Feld wieder aus der Nachricht gelöscht.  
  
Ein Manko wollen wir nicht verschweigen: Sie haben leider keine Wahl, auf welchem Drucker die Nachricht ausgegeben wird. Der VBA-Befehl "Printout" greift immer auf den Standarddrucker zurück. Ändern Sie vor dem Druckvorgang also gegebenenfalls Ihren Standarddrucker.